【VB】使用GDI实现整张位图颜色相加 AdditionBlt

0xAA55

其中实例窗口中用户每次拖动鼠标，程序都会在鼠标经过的区域不断用颜色相加的方式绘制一张如下位图。

这张位图来源于DXSDK8中的Media文件夹中的particle.bmp

所谓的整张位图颜色相加，与透明混合不同，是『目标颜色 = (源 + 目标) > 1 ? 1 : (源 + 目标)』。GDI的AlphaBlend函数本身是被设计用来进行透明混合的，它本身对每个像素进行如下的计算：

如果源图有透明通道：
Dest = Dest * (1 - Src.Alpha * SCA) + Src * SCA
如果源图没有透明通道：
Dest = Dest * (1 - SCA) + Src * SCA

也就是说，本身透明混合的计算里面，源图应该要乘以自己的透明通道值的，但是AlphaBlend忽略了这样的计算，也就是如果你的Src.Alpha为0，那么它就完全进行颜色的加法了——然而并不是，当你Src.Alpha为0时它认为这个像素是全透明的。。但Src.Alpha为1的时候是可以的（相当于0.5 % 不透明度，十分接近0了）
所以我们只需要将源图的Alpha通道设置为1，就可以用它做加法计算了？虽然是这样，但是它不会做溢出处理，如果你的源颜色值加上目标颜色值大于255，它就会只保留低8位，造成回滚——两个比较亮的颜色相加后实际成为了一个比较黑的颜色。这种溢出如果被我们自己处理的话，就能被解决。

因为从二进制加法的角度解释这个就是，每个颜色通道都是8bit，当它们最高位都是1，然后相加以后，就会进位，进的位会被丢弃所以就会出现回卷现象。而我们如何才能判断哪些像素在高亮的地方发生了进位呢？我的方法是，将两张需要做加法混合的图，亮度都减少一半。这相当于它们每个通道的颜色值除以2，或者右移1位。经过这样的处理以后，再做加法混合，颜色通道的第7bit——最高位，就是原先应该被丢弃掉的第8bit，也就是进位了。这个时候用位域运算，用BitBlt将一个全图全通道都是0x80的纯色图做SRCAND就可以提取出所有的进位了的部分了。
将两张图减少亮度然后相加，其实可以直接一步搞定——直接用AlphaBlend将两张图进行透明混合，透明度为50%。
提取了进位后，再用AlphaBlend将其亮度降低——用一张纯黑的图以1/255的比例进行透明混合，相当于它的每个颜色都减去1，那么这些溢出过的颜色就会从0x80变成0x7F，然后再和0x80筛选出来的图做SRCPAINT（或运算）就能将所有溢出过的像素Clamp到255亮度而不会发生回卷——丢弃最高位的行为。这样得到的图再拿去和之前直接做加法混合的图做SRCPAINT混合，就能得到带亮度限定、溢出部分全亮处理的两图叠加图了。
但是因为AlphaBlend不会对不透明度为0的像素做处理，然后GDI的图像通常不带Alpha通道，因此需要手动处理，建立一张32bit真彩色位图（Win7用CreateCompatibleBitmap就可以建立默认位数32的位图，但XP下你会得到24bit、16bit的位图，此时应该建立DIBSection，然而这样的话它估计就是纯CPU运算了，达不到光栅显卡加速的效果——然而现在大家用的显卡都是图形卡，应该是没有光栅加速效果的吧，但做透明混合的时候应该也是多少有些帮助的），然后手动将所有像素的不透明通道设为0.5%（也就是1，最大值255的），再用AlphaBlend就可以做加法混合了。但是这样一来，每次经过处理以后，原先被加亮绘图覆盖的部分将会稍微变黑——因为被AlphaBlend经过不透明通道为1的混合处理以后，根据计算式Dest = Dest * 0.95 + Src，颜色值大于127的部分会被减去1.这是这种处理方式的缺陷啦。做少量的加法混合图的时候，这种现象应该是几乎不会引起人的注意的。
如果要做到完美的处理，就只能自己操作Bit了——这样还能保证，它是一定不会进行显卡加速的！（当然是坏消息，有显卡加速才是更好的做法，所以我才会用这些API）

模块 modAdditionBlt：

1. Option Explicit
   
2. 
   
3. Private Declare Function Rectangle Lib "gdi32" (ByVal hDC As Long, ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
   
4. Private Declare Function GetStockObject Lib "gdi32" (ByVal nIndex As Long) As Long
   
5. Private Declare Function CreatePen Lib "gdi32" (ByVal nPenStyle As Long, ByVal nWidth As Long, ByVal crColor As Long) As Long
   
6. Private Declare Function SetROP2 Lib "gdi32" (ByVal hDC As Long, ByVal nDrawMode As Long) As Long
   
7. Private Declare Function SelectObject Lib "gdi32" (ByVal hDC As Long, ByVal hObject As Long) As Long
   
8. Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
   
9. 
   
10. Private Const PS_SOLID = 0
    
11. Private Const R2_MASKPEN = 9     '  DPa
    
12. Private Const GRAY_BRUSH = 2
    
13. Private Const BLACK_BRUSH = 4
    
14. Private Const NULL_PEN = 8
    
15. 
    
16. Type AdditionBitmap_t
    
17.     Width As Long
    
18.     Height As Long
    
19.     OrigPic As Bit32_Picture
    
20.     Temp1 As Bit32_Picture
    
21.     Temp2 As Bit32_Picture
    
22. End Type
    
23. 
    
24. Function AdditionBitmap_Create(ByVal hDC As Long, ByVal bmWidth As Long, ByVal bmHeight As Long, ByVal hSrcDC As Long) As AdditionBitmap_t
    
25. AdditionBitmap_Create.Width = bmWidth
    
26. AdditionBitmap_Create.Height = bmHeight
    
27. AdditionBitmap_Create.OrigPic = Bit32_Create(hDC, bmWidth, bmHeight) '图像资源
    
28. AdditionBitmap_Create.Temp1 = Bit32_Create(hDC, bmWidth, bmHeight) '临时图像1
    
29. AdditionBitmap_Create.Temp2 = Bit32_Create(hDC, bmWidth, bmHeight) '临时图像2
    
30. BitBlt AdditionBitmap_Create.OrigPic.hDC, 0, 0, bmWidth, bmHeight, hSrcDC, 0, 0, vbSrcCopy '复制图像资源，强行适应格式
    
31. Bit32_SetAlpha AdditionBitmap_Create.OrigPic, 1 '设置Alpha通道值全为1（%0.5不透明度，但不预乘Alpha值。设为0就不显示了只好设为1）
    
32. 
    
33. '临时图像1，高位（溢出）检测用
    
34. '临时图像2，用于合并所有的图
    
35. 
    
36. SetROP2 AdditionBitmap_Create.Temp1.hDC, R2_MASKPEN 'And模式
    
37. SelectObject AdditionBitmap_Create.Temp1.hDC, GetStockObject(NULL_PEN)
    
38. SelectObject AdditionBitmap_Create.Temp1.hDC, GetStockObject(GRAY_BRUSH) '颜色是&H808080
    
39. SelectObject AdditionBitmap_Create.Temp2.hDC, GetStockObject(BLACK_BRUSH)
    
40. End Function
    
41. 
    
42. Sub AdditionBitmap_Delete(AdditionBitmap As AdditionBitmap_t)
    
43. Bit32_Delete AdditionBitmap.OrigPic
    
44. Bit32_Delete AdditionBitmap.Temp1
    
45. Bit32_Delete AdditionBitmap.Temp2
    
46. End Sub
    
47. 
    
48. Sub AdditionBlt(ByVal hDestDC As Long, ByVal X As Long, ByVal Y As Long, ByVal nWidth As Long, ByVal nHeight As Long, SrcBitmap As AdditionBitmap_t, ByVal SrcX As Long, ByVal SrcY As Long)
    
49. '直接用AlphaBlend做图像加法会有饱和部分，由于它默认不处理，会导致回卷。因此要手动提取饱和部分，将其设为全1，再合并
    
50. 
    
51. '提取饱和部分
    
52. BitBlt SrcBitmap.Temp1.hDC, 0, 0, nWidth, nHeight, hDestDC, X, Y, vbSrcCopy
    
53. AlphaBlend SrcBitmap.Temp1.hDC, 0, 0, nWidth, nHeight, SrcBitmap.OrigPic.hDC, SrcX, SrcY, nWidth, nHeight, &H800000 '混合为半亮图
    
54. Rectangle SrcBitmap.Temp1.hDC, 0, 0, nWidth + 1, nHeight + 1 '取得每通道位面7的部分（Rectangle的宽高要加1）
    
55. Rectangle SrcBitmap.Temp2.hDC, 0, 0, nWidth + 1, nHeight + 1 '清空临时图片2
    
56. AlphaBlend SrcBitmap.Temp2.hDC, 0, 0, nWidth, nHeight, SrcBitmap.Temp1.hDC, 0, 0, nWidth, nHeight, &HFE0000 '半亮图每通道亮度-1
    
57. BitBlt SrcBitmap.Temp2.hDC, 0, 0, nWidth, nHeight, SrcBitmap.Temp1.hDC, 0, 0, vbSrcPaint '合并高位，完成二值化处理
    
58. 'SrcBitmap.Temp2: 半亮图位面7每通道二值化（饱和部分）
    
59. 
    
60. '合成全亮图
    
61. AlphaBlend hDestDC, X, Y, nWidth, nHeight, SrcBitmap.OrigPic.hDC, SrcX, SrcY, nWidth, nHeight, &H1FF0000 '完全加法
    
62. '就是这个完全加法会导致被遮盖的图发生灰化，但目前没办法解决。。除非源图Alpha设为0时它也做渲染处理
    
63. BitBlt hDestDC, X, Y, nWidth, nHeight, SrcBitmap.Temp2.hDC, 0, 0, vbSrcPaint '合并饱和部分
    
64. End Sub

复制代码

模块 Bit32：

1. Option Explicit
   
2. 
   
3. Private Type BITMAPINFOHEADER '40 bytes
   
4.     biSize As Long
   
5.     biWidth As Long
   
6.     biHeight As Long
   
7.     biPlanes As Integer
   
8.     biBitCount As Integer
   
9.     biCompression As Long
   
10.     biSizeImage As Long
    
11.     biXPelsPerMeter As Long
    
12.     biYPelsPerMeter As Long
    
13.     biClrUsed As Long
    
14.     biClrImportant As Long
    
15. End Type
    
16. 
    
17. Type BLENDFUNCTION
    
18.     BlendOp As Byte
    
19.     BlendFlags As Byte
    
20.     SCA As Byte
    
21.     AlphaFormat As Byte
    
22. End Type
    
23. 
    
24. Type ARGB
    
25.     B As Byte
    
26.     G As Byte
    
27.     R As Byte
    
28.     A As Byte
    
29. End Type
    
30. 
    
31. Private Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hDC As Long) As Long
    
32. Private Declare Function CreateCompatibleBitmap Lib "gdi32" (ByVal hDC As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long
    
33. Private Declare Function GetDIBits Lib "gdi32" (ByVal hDC As Long, ByVal hBitmap As Long, ByVal nStartScan As Long, ByVal nNumScans As Long, lpBits As Any, lpBI As BITMAPINFOHEADER, ByVal wUsage As Long) As Long
    
34. Private Declare Function SetDIBits Lib "gdi32" (ByVal hDC As Long, ByVal hBitmap As Long, ByVal nStartScan As Long, ByVal nNumScans As Long, lpBits As Any, lpBI As BITMAPINFOHEADER, ByVal wUsage As Long) As Long
    
35. Private Declare Function CreateDIBSection Lib "gdi32" (ByVal hDC As Long, pBitmapInfo As Any, ByVal un As Long, ppBits As Long, ByVal handle As Long, ByVal dw As Long) As Long
    
36. Private Declare Function SelectObject Lib "gdi32" (ByVal hDC As Long, ByVal hObject As Long) As Long
    
37. Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
    
38. Private Declare Function DeleteDC Lib "gdi32" (ByVal hDC As Long) As Long
    
39. Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
    
40. Declare Function BitBlt Lib "gdi32" (ByVal hDestDC As Long, ByVal X As Long, ByVal Y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long
    
41. Declare Function AlphaBlend Lib "msimg32" (ByVal hDC As Long, ByVal X As Long, ByVal Y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal nSrcWidth As Long, ByVal nSrcHeight As Long, ByVal dwRop As Long) As Long
    
42. Private Declare Function GetDeviceCaps Lib "gdi32" (ByVal hDC As Long, ByVal nIndex As Long) As Long
    
43. Private Const BITSPIXEL = 12         '  Number of bits per pixel
    
44. 
    
45. Const AC_SRC_OVER As Long = 0
    
46. Const AC_SRC_ALPHA As Long = 1
    
47. 
    
48. Type Bit32_Picture
    
49.     hDC As Long
    
50.     hBmp As Long '只能用于上面定义的hDC
    
51.     pBits As Long '-1表示DDB
    
52.     Width As Long
    
53.     Height As Long
    
54. End Type
    
55. 
    
56. Function Bit32_Create(ByVal hDC As Long, ByVal bmWidth As Long, ByVal bmHeight As Long) As Bit32_Picture
    
57. Dim hNewDC As Long, hNewBmp As Long, pBits As Long
    
58. hNewDC = CreateCompatibleDC(hDC)
    
59. 
    
60. '如果用CreateCompatibleBitmap创建的不是32bit位图，就创建DIB，否则创建DDB
    
61. If GetDeviceCaps(hNewDC, BITSPIXEL) <> 32 Then
    
62.     Dim BMIF As BITMAPINFOHEADER
    
63.     With BMIF
    
64.         .biSize = 40
    
65.         .biWidth = bmWidth
    
66.         .biHeight = bmHeight
    
67.         .biPlanes = 1
    
68.         .biBitCount = 32
    
69.         .biSizeImage = bmWidth * bmHeight * 4
    
70.     End With
    
71.     hNewBmp = CreateDIBSection(hNewDC, BMIF, 0, pBits, 0, 0)
    
72.     SelectObject hNewDC, hNewBmp
    
73.     DeleteObject hNewBmp
    
74. Else
    
75.     '创建DDB
    
76.     hNewBmp = CreateCompatibleBitmap(hDC, bmWidth, bmHeight)
    
77.     pBits = -1
    
78.     SelectObject hNewDC, hNewBmp
    
79.     DeleteObject hNewBmp
    
80. End If
    
81. Bit32_Create.hDC = hNewDC
    
82. Bit32_Create.hBmp = hNewBmp
    
83. Bit32_Create.pBits = pBits
    
84. Bit32_Create.Width = bmWidth
    
85. Bit32_Create.Height = bmHeight
    
86. End Function
    
87. 
    
88. Sub Bit32_Delete(Bit32 As Bit32_Picture)
    
89. If Bit32.hDC Then DeleteDC Bit32.hDC
    
90. Bit32.hDC = 0
    
91. End Sub
    
92. 
    
93. '设置整张图的Alpha透明通道
    
94. Sub Bit32_SetAlpha(Bit32 As Bit32_Picture, Optional ByVal Alpha As Byte = &HFF&, Optional ByVal SetBits As Boolean = False)
    
95. Dim Colors() As ARGB
    
96. ReDim Colors(Bit32.Width * Bit32.Height - 1)
    
97. 
    
98. '如果是DIB则直接操作pBits，否则用GetDIBits、SetDIBits操作位图数据
    
99. If Bit32.pBits = -1 Then
    
100.     Dim BMIF As BITMAPINFOHEADER
     
101.     With BMIF
     
102.         .biSize = 40
     
103.         .biWidth = Bit32.Width
     
104.         .biHeight = Bit32.Height
     
105.         .biPlanes = 1
     
106.         .biBitCount = 32
     
107.         .biSizeImage = Bit32.Width * Bit32.Height * 4
     
108.     End With
     
109.     GetDIBits Bit32.hDC, Bit32.hBmp, 0, Bit32.Height, Colors(0), BMIF, 0
     
110. Else
     
111.     CopyMemory Colors(0), ByVal Bit32.pBits, Bit32.Width * Bit32.Height * 4
     
112. End If
     
113. 
     
114. '设置透明通道
     
115. Dim I&
     
116. For I = 0 To UBound(Colors)
     
117.     Colors(I).A = Alpha
     
118. Next
     
119. '如果需要预乘透明度值，则进行处理
     
120. If SetBits Then
     
121.     'Alpha = 255 - Alpha
     
122.     For I = 0 To UBound(Colors)
     
123.         Colors(I).R = CLng(Colors(I).R) * Alpha / 255
     
124.         Colors(I).G = CLng(Colors(I).G) * Alpha / 255
     
125.         Colors(I).B = CLng(Colors(I).B) * Alpha / 255
     
126.     Next
     
127. End If
     
128. 
     
129. '提交更改
     
130. If Bit32.pBits = -1 Then
     
131.     SetDIBits Bit32.hDC, Bit32.hBmp, 0, Bit32.Height, Colors(0), BMIF, 0
     
132. Else
     
133.     CopyMemory ByVal Bit32.pBits, Colors(0), Bit32.Width * Bit32.Height * 4
     
134. End If
     
135. End Sub

复制代码

BIN: AdditionBlt_Bin.7z (11.67 KB, 下载次数: 31)

2016-5-21 16:13 上传

点击文件名下载附件

名称: AdditionBlt_Bin.7z
大小: 11947 字节
SHA256: 95CD011E880F51D01FBA91BFD1FE4CD59C092D509D8BD6F1F5A313184AD2A92D

源码：

游客，如果您要查看本帖隐藏内容请回复

zcjhy

真的不错的效果

二十六

学习一下

qxinfo

】使用GDI实现整张位图颜色相加 AdditionBlt [修改]

阿呆在上海

好好学习，图像问题很难

Phalcon

是调用GDI的函数

0xAA55

Phalcon 发表于 2018-2-11 15:55
是调用GDI的函数

对。并且是想要避开自己进行颜色计算的。

0xAA55

有优化大概是错觉……

ky52879

看看源码，想学

bigwind

SHA256: 95CD011E880F51D01FBA91BFD1FE4CD59C092D509D8BD6F1F5A313184AD2A92D

系统消息

还是用 _mm_adds_epu8 直接一次性批量计算16个字节无符号8位饱和加法最高效，VB6可以通过ShellCode来做这个优化，或者用VC写个dll来调用。

0xAA55

系统消息 发表于 2019-11-1 16:00
还是用 _mm_adds_epu8 直接一次性批量计算16个字节无符号8位饱和加法最高效，VB6可以通过ShellCode来做这个 ...

考虑到DWM开启Aero环境下、GDI接口可能有部分是GPU负责的（封装得类似于低效的GPU驱动的可能性是有的），暂且考虑了如此的方式，通过API来做这些事，而非自己写算法。

虽说，流式SIMD进行整张位图处理的方式也十分像GPU的行为，并且也是一种高效的CPU渲染的方式。只是，Windows在实现GDI的时候，应该已经用了类似的指令集。

系统消息

0xAA55 发表于 2019-11-6 15:21
考虑到DWM开启Aero环境下、GDI接口可能有部分是GPU负责的（封装得类似于低效的GPU驱动的可能性是有的）， ...

主要是GDI没有提供对线性减淡混合的实现，还有就是DIB位图不会有GPU加速吧，我现在写GDI程序一般都是DIB位图操作。

hxin123456

看看学习下

大宝

怎样用VB6编辑位图颜色

东东哥

叫你隐藏，抓出来。

xiongsx

王王王王王王王王王王王王王王王王王王王王王

xiawan

感谢楼主分享~~~