【汇编】最简单的切保护模式的源码

0xAA55

1. bits 16
   
2. org 0x7c00
   
3. 
   
4. Start:
   
5. xor ax,ax
   
6. mov ds,ax
   
7. 
   
8. cli
   
9. 
   
10. lgdt [GDTR]
    
11. 
    
12. mov eax,cr0
    
13. or al,1
    
14. mov cr0,eax
    
15. jmp dword 0x08:PEStart
    
16. 
    
17. GDTR:
    
18. .limit:
    
19. dw GDT.End-GDT-1
    
20. .base:
    
21. dd GDT
    
22. 
    
23. GDT:
    
24. dw 0,0,0,0
    
25. 
    
26. dw 0xffff
    
27. dw 0
    
28. dw 0x9a00
    
29. dw 0x00cf
    
30. 
    
31. dw 0xffff
    
32. dw 0
    
33. dw 0x9200
    
34. dw 0x00cf
    
35. .End:
    
36. 
    
37. PEStart:
    
38. bits 32
    
39. 
    
40. mov ax,0x10
    
41. mov es,ax
    
42. mov ss,ax
    
43. mov ds,ax
    
44. mov fs,ax
    
45. mov gs,ax
    
46. mov esp, 0xffff
    
47. 
    
48. .text:
    
49. mov dword[0xb8000],'P'|('r'<<16)|0x07000700
    
50. mov dword[0xb8004],'o'|('t'<<16)|0x07000700
    
51. mov dword[0xb8008],'e'|('c'<<16)|0x07000700
    
52. mov dword[0xb800c],'t'|('e'<<16)|0x07000700
    
53. mov dword[0xb8010],'d'|(' '<<16)|0x07000700
    
54. mov dword[0xb8014],'m'|('o'<<16)|0x07000700
    
55. mov dword[0xb8018],'d'|('e'<<16)|0x07000700
    
56. jmp .text
    
57. 
    
58. times 510-($-$$) db 0
    
59. dw 0xAA55

复制代码

编译为平坦格式flp后缀，让vmware把它当作一个启动软盘加载即可运行。
没有出问题的话，它应该会显示一句“Protected mode”。

细节上要注意的点：
1、切模式前务必关中断。用cli即可。如果只是想进保护模式玩玩的话，无需设置IDT和TS。
2、nasm编译器，我用的版本是2.13.01。经过我的测试2.11版有BUG，会导致它无视你的bits 32语句。
3、修改cr0的数值后必须立即跳转。
4、可以不用在跳转前修改段选择子。
5、开头的那几句：
    xor ax,ax
    mov ds,ax
经测试，必须要有。因为引导进来的时候ds并没有指向你的代码所在的段上。不设置这两句的话，lgdt指令并不能正确找到你的gdt表。

Ayala

用masm写起来就恶心了 dos bin

1. DESC STRUC
   
2.         lim_00_15 DW ?
   
3.         bas_00_15 DW ?
   
4.         bas_16_23 DB ?
   
5.         access    DB ?
   
6.         gran      DB ?
   
7.         bas_24_31 DB ?
   
8. DESC ENDS
   
9. 
   
10. data segment
    
11.         GDT_REG label DESC
    
12.         ;cs 0
    
13.                                 dw 0
    
14.                                
    
15.                                 dw 0
    
16.                                
    
17.                                 db 0
    
18.                                 db 0
    
19.                                
    
20.                                 db 0
    
21.                                 db 0
    
22.         ;cs 08h
    
23.                                 dw 0FFFFh
    
24.                                 dw 0
    
25.                                
    
26.                                 db 0
    
27.                                 db 9ah
    
28.                                
    
29.                                 db 0cfh
    
30.                                 db 0
    
31.         ;es 10h
    
32.                                 dw 0FFFFh
    
33.                                 dw 0
    
34.                                
    
35.                                 db 0
    
36.                                 db 92h
    
37.                                
    
38.                                 db 0cfh
    
39.                                 db 0
    
40.         ;ss 18h
    
41.                                 dw 0FFFFh
    
42.                                 dw 0
    
43.                                
    
44.                                 db 0
    
45.                                 db 92h
    
46.                                
    
47.                                 db 0cfh
    
48.                                 db 0
    
49.         GDT_LENGTH  EQU $ - offset GDT_REG
    
50.        
    
51.        
    
52.         GDTR_org         dw 0
    
53.                                 dd 0
    
54.         GDTR_new        dw GDT_LENGTH - 1
    
55.                                 dd offset GDT_REG
    
56. data ends
    
57. 
    
58. 
    
59. u16 segment
    
60.         assume cs:u16,ds:data
    
61. REAL_MODE:
    
62. 
    
63. start:
    
64.         mov ax,data
    
65.         mov ds,ax
    
66. 
    
67.         mov ax,u32
    
68. .386
    
69.         shl eax,4
    
70. .8086
    
71.         mov GDT_REG[8].bas_00_15,ax
    
72. .386       
    
73.         shr eax,16
    
74. .8086
    
75.         mov GDT_REG[8].bas_16_23,al
    
76.         mov GDT_REG[8].bas_24_31,ah
    
77.        
    
78.         mov ax,data
    
79. .386
    
80.         shl eax,4
    
81.         add eax,dword ptr ds:GDTR_new[2]
    
82.         mov dword ptr ds:GDTR_new[2],eax
    
83.        
    
84. .386p
    
85.         cli
    
86.         db 66h       
    
87.         sgdt fword ptr ds:[GDTR_org]
    
88.        
    
89.         db 66h
    
90.         lgdt fword ptr ds:[GDTR_new]
    
91. 
    
92.         mov eax,cr0
    
93.         or  eax,1
    
94.         mov cr0,eax
    
95.        
    
96.         db 66h
    
97.         db 0eah
    
98.         dd 0
    
99.         dw 8
    
100. 
     
101. u16 ends
     
102. 
     
103. .386
     
104. 
     
105. u32 segment use32
     
106. PROTECT_MODE:
     
107. 
     
108.         mov ax,10h
     
109.         mov es,ax
     
110. 
     
111.         mov edi,0b8000h
     
112.         mov ecx,80*25
     
113.         mov al,"*"
     
114.         mov ah,11001010b
     
115.         rep stosw
     
116.        
     
117.         jmp $
     
118.        
     
119. u32 ends
     
120. 
     
121. end start
     

复制代码

0xAA55

Ayala 发表于 2017-6-15 19:56
用masm写起来就恶心了 dos bin
[code]DESC STRUC
        lim_00_15 DW ?

这db 66h让我回忆起了曾经的辛酸

Ayala

0xAA55 发表于 2017-6-15 21:06
这db 66h让我回忆起了曾经的辛酸

这种写法 最早出自intel自己呢！

(⊙o⊙)

这也可以。