vb StringBuilder类

天马座

此类主要解决vb字符串频繁连接速度慢的问题，支持UTF-8 UTF-16互转，其他功能陆续添加

1. 
   
2. Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal length As Long)
   
3. Private s As String
   
4. Private size As Long, capacity As Long
   
5. Private Sub Class_Initialize()
   
6.     size = 0
   
7.     capacity = 8
   
8.     s = String(capacity \ 2, ChrW(0))
   
9. End Sub
   
10. Public Function length() As Long
    
11.     '返回字符串长度 宽字节
    
12.     length = size \ 2
    
13. End Function
    
14. Public Function lengthB() As Long
    
15.     '返回字符串长度 字节
    
16.     lengthB = size
    
17. End Function
    
18. Public Sub clear()
    
19.     '清除缓冲区
    
20.     size = 0
    
21.     capacity = 8
    
22.     s = String(capacity \ 2, ChrW(0))
    
23. End Sub
    
24. Public Sub append(ByRef value As String)
    
25.     '添加
    
26.     Call copyB(value, size)
    
27. End Sub
    
28. Public Sub copy(ByRef value As String, ByVal index As Long)
    
29.     '写入 index对应宽字节 put命名被占用 改为copy
    
30.     Call copyB(value, index * 2)
    
31. End Sub
    
32. Public Sub copyB(ByRef value As String, ByVal index As Long)
    
33.     '写入 index对应字节
    
34.     If index < 0 Or index > size Or LenB(value) = 0 Then
    
35.         Exit Sub
    
36.     End If
    
37.     Dim n As Long
    
38.     n = LenB(value)
    
39.     Call ensureCapacity(index + n)
    
40.     Call CopyMemory(ByVal unsignedAdd(StrPtr(s), index), ByVal StrPtr(value), n)
    
41.     If size < index + n Then
    
42.          size = index + n
    
43.     End If
    
44. End Sub
    
45. Public Sub insert(ByRef value As String, ByVal index As Long)
    
46.     '插入 index对应宽字节
    
47.     Call insertB(value, index * 2)
    
48. End Sub
    
49. Public Sub insertB(ByRef value As String, ByVal index As Long)
    
50.     '插入 index对应字节
    
51.     If index < 0 Or index > size Or LenB(value) = 0 Then
    
52.         Exit Sub
    
53.     End If
    
54.     Dim n As Long
    
55.     n = LenB(value)
    
56.     Call ensureCapacity(size + n)
    
57.     If index <> size Then
    
58.            Call CopyMemory(ByVal unsignedAdd(StrPtr(s), index + n), ByVal unsignedAdd(StrPtr(s), index), size - index)
    
59.     End If
    
60.     Call CopyMemory(ByVal unsignedAdd(StrPtr(s), index), ByVal StrPtr(value), n)
    
61.     size = size + n
    
62. End Sub
    
63. Public Sub remove(ByVal index As Long)
    
64.     '删除 index对应宽字节
    
65.     Call removeRange0(index * 2, 2)
    
66. End Sub
    
67. Public Sub removeB(ByVal index As Long)
    
68.     '删除 index对应字节
    
69.     Call removeRange0(index, 1)
    
70. End Sub
    
71. Public Sub removeRange(ByVal lo As Long, ByVal hi As Long)
    
72.     '删除 [lo..hi]对应宽字节
    
73.     Call removeRange0(lo * 2, (hi - lo + 1) * 2)
    
74. End Sub
    
75. Public Sub removeRangeB(ByVal lo As Long, ByVal hi As Long)
    
76.      '删除 [lo..hi]对应字节
    
77.      Call removeRange0(lo, hi - lo + 1)
    
78. End Sub
    
79. Private Sub removeRange0(ByVal lo As Long, ByVal n As Long)
    
80.     If n <= 0 Or lo < 0 Or lo + n > size Then
    
81.         Exit Sub
    
82.     End If
    
83.     If size - (lo + n) > 0 Then
    
84.         Call CopyMemory(ByVal unsignedAdd(StrPtr(s), lo), ByVal unsignedAdd(StrPtr(s), lo + n), size - (lo + n))
    
85.     End If
    
86.     size = size - n
    
87. End Sub
    
88. Public Sub replaceRange(ByVal lo As Long, ByVal hi As Long, ByRef oldValue As String, ByRef nweValue As String)
    
89.     '替换[lo..hi]对应宽字节
    
90.     Call replaceRangeB(lo * 2, hi * 2, oldValue, nweValue)
    
91. End Sub
    
92. Public Sub replaceRangeB(ByVal lo As Long, ByVal hi As Long, ByRef oldValue As String, ByRef nweValue As String)
    
93.     '替换[lo..hi]对应字节
    
94.     If lo < 0 Or hi >= size Or LenB(oldValue) = 0 Then
    
95.         Exit Sub
    
96.     End If
    
97.     Dim start As Long, i As Long, oldLength As Long
    
98.     Dim update As Boolean
    
99.     Dim src As String
    
100.     Dim sb As New StringBuilder
     
101.     src = toString()
     
102.     update = False
     
103.     oldLength = LenB(oldValue)
     
104.     i = lo + 1
     
105.     start = lo + 1
     
106.     Do While i <= hi + 1
     
107.         i = InStrB(i, src, oldValue)
     
108.         If i < 1 Then
     
109.             If update Then
     
110.                 sb.append MidB(src, start, hi + 2 - start)
     
111.             End If
     
112.             Exit Do
     
113.         End If
     
114.         sb.append MidB(src, start, i - start)
     
115.         sb.append nweValue
     
116.         i = i + oldLength
     
117.         start = i
     
118.         update = True
     
119.     Loop
     
120.     If update Then
     
121.         Call removeRangeB(lo, hi)
     
122.         Call insertB(sb.toString, lo)
     
123.     End If
     
124.     Set sb = Nothing
     
125. End Sub
     
126. Public Function toString() As String
     
127.     '返回缓冲区中的字符串
     
128.     toString = MidB(s, 1, size)
     
129. End Function
     
130. 
     
131. 
     
132. Private Function unsignedAdd(a As Long, b As Long) As Long
     
133.    If (a Xor b) And &H80000000 Then
     
134.       unsignedAdd = a + b
     
135.    Else
     
136.       unsignedAdd = (a Xor &H80000000) + b Xor &H80000000
     
137.    End If
     
138. End Function
     
139. Private Sub ensureCapacity(ByVal minCapacity As Long)
     
140.     If capacity >= minCapacity Then
     
141.         Exit Sub
     
142.     End If
     
143.     Dim newCapacity As Long
     
144.     newCapacity = capacity
     
145.     Do While newCapacity < minCapacity
     
146.         newCapacity = newCapacity + newCapacity
     
147.     Loop
     
148.     s = s & String((newCapacity - capacity) \ 2, ChrW(0))
     
149.     capacity = newCapacity
     
150. End Sub
     
151. 
     

复制代码

Ink_Hin_fifteen

没有示例的代码,差评。

天马座

Ink_Hin_fifteen 发表于 2019-7-25 20:29
没有示例的代码,差评。

后续会添加